feat: initial fish shell configuration

- Core config layered on CachyOS base with Catppuccin Mocha theming
- Fisher plugins: fzf.fish, catppuccin, autopair, replay, puffer-fish, magic-enter, spark
- Smart CLI wrappers with fallbacks (bat, lsd, btop, dust, prettyping)
- Custom functions: git, docker, network, kitty, AI session management
- Extensive abbreviation system for keyboard-driven workflows
- Secrets/local sourcing pattern for private and machine-specific config
- README with full documentation and personalization guide
- AGPLv3+ license with copyright headers on all source files

conf.d/puffer_fish_key_bindings.fish

@@ -0,0 +1,27 @@
+status is-interactive || exit
+
+function _puffer_fish_key_bindings --on-variable fish_key_bindings
+    set -l modes
+    if test "$fish_key_bindings" = fish_default_key_bindings
+        set modes default insert
+    else
+        set modes insert default
+    end
+
+    bind --mode $modes[1] '.' _puffer_fish_expand_dot
+    bind --mode $modes[1] '!' _puffer_fish_expand_bang
+    bind --mode $modes[1] '$' _puffer_fish_expand_buck
+    bind --mode $modes[1] '*' _puffer_fish_expand_star
+    bind --mode $modes[2] --erase '.' '!' '$' '*'
+end
+
+_puffer_fish_key_bindings
+
+set -l uninstall_event puffer_fish_key_bindings_uninstall
+
+function _$uninstall_event --on-event $uninstall_event
+    bind -e '.'
+    bind -e '!'
+    bind -e '$'
+    bind -e '*'
+end