rootiest
4c1e7a7eb9
- Core config layered on CachyOS base with Catppuccin Mocha theming - Fisher plugins: fzf.fish, catppuccin, autopair, replay, puffer-fish, magic-enter, spark - Smart CLI wrappers with fallbacks (bat, lsd, btop, dust, prettyping) - Custom functions: git, docker, network, kitty, AI session management - Extensive abbreviation system for keyboard-driven workflows - Secrets/local sourcing pattern for private and machine-specific config - README with full documentation and personalization guide - AGPLv3+ license with copyright headers on all source files
28 lines
1.3 KiB
Fish
28 lines
1.3 KiB
Fish
# fzf.fish is only meant to be used in interactive mode. If not in interactive mode and not in CI, skip the config to speed up shell startup
|
|
if not status is-interactive && test "$CI" != true
|
|
exit
|
|
end
|
|
|
|
# Because of scoping rules, to capture the shell variables exactly as they are, we must read
|
|
# them before even executing _fzf_search_variables. We use psub to store the
|
|
# variables' info in temporary files and pass in the filenames as arguments.
|
|
# This variable is global so that it can be referenced by fzf_configure_bindings and in tests
|
|
set --global _fzf_search_vars_command '_fzf_search_variables (set --show | psub) (set --names | psub)'
|
|
|
|
# Install the default bindings, which are mnemonic and minimally conflict with fish's preset bindings
|
|
fzf_configure_bindings
|
|
|
|
# Doesn't erase autoloaded _fzf_* functions because they are not easily accessible once key bindings are erased
|
|
function _fzf_uninstall --on-event fzf_uninstall
|
|
_fzf_uninstall_bindings
|
|
|
|
set --erase _fzf_search_vars_command
|
|
functions --erase _fzf_uninstall _fzf_migration_message _fzf_uninstall_bindings fzf_configure_bindings
|
|
complete --erase fzf_configure_bindings
|
|
|
|
set_color cyan
|
|
echo "fzf.fish uninstalled."
|
|
echo "You may need to manually remove fzf_configure_bindings from your config.fish if you were using custom key bindings."
|
|
set_color normal
|
|
end
|