rootiest
4c51ef7a33
Records each documented function's manual category in its own header, so Section 5 can later be generated from source instead of hand-maintained alongside it. Values reproduce the current grouping in docs/manual/05-functions/ exactly; no documentation changes meaning here. Four functions are skipped because they have no header at all yet (branch, fc, gitup, sudo-toggle); they get one in the merge that follows.
73 lines
2.7 KiB
Fish
73 lines
2.7 KiB
Fish
# Copyright (C) 2026 Rootiest
|
|
# SPDX-License-Identifier: AGPL-3.0-or-later
|
|
|
|
# CATEGORY
|
|
# 14-miscellaneous
|
|
#
|
|
# SYNOPSIS
|
|
# replay <commands>
|
|
#
|
|
# DESCRIPTION
|
|
# Runs the given commands in Bash and replays any resulting environment
|
|
# variable, alias, and directory changes back into the current Fish
|
|
# session. Useful for sourcing Bash-only scripts.
|
|
#
|
|
# ARGUMENTS
|
|
# commands Bash command string to execute and replay
|
|
#
|
|
# RETURNS
|
|
# 0 Commands ran successfully and changes were replayed
|
|
# 1 Bash command exited with a non-zero status
|
|
#
|
|
# EXAMPLE
|
|
# replay "source ~/.bashrc"
|
|
# replay "export FOO=bar"
|
|
function replay --description 'Run Bash commands replaying changes in Fish'
|
|
switch "$argv"
|
|
case -v --version
|
|
echo "replay, version 1.2.1"
|
|
case "" -h --help
|
|
echo "Usage: replay <commands> Run Bash commands replaying changes in Fish"
|
|
echo "Options:"
|
|
echo " -v or --version Print version"
|
|
echo " -h or --help Print this help message"
|
|
case \*
|
|
set --local env
|
|
set --local sep @$fish_pid(random)(command date +%s)
|
|
set --local argv $argv[1] (string escape -- $argv[2..-1])
|
|
set --local out (command bash -c "
|
|
$argv
|
|
status=\$?
|
|
[ \$status -gt 0 ] && exit \$status
|
|
|
|
command compgen -e | command awk -v sep=$sep '{
|
|
gsub(/\n/, \"\\\n\", ENVIRON[\$0])
|
|
print \$0 sep ENVIRON[\$0]
|
|
}' && alias
|
|
") || return
|
|
|
|
string replace --all -- \\n \n (
|
|
for line in $out
|
|
if string split -- $sep $line | read --local --line name value
|
|
set --append env $name
|
|
|
|
contains -- $name SHLVL PS1 BASH_FUNC || test "$$name" = "$value" && continue
|
|
|
|
if test "$name" = PATH
|
|
echo set PATH (string split -- : $value | string replace --regex --all -- '(^.*$)' '"$1"')
|
|
else if test "$name" = PWD
|
|
echo builtin cd "\"$value\""
|
|
else
|
|
echo "set --global --export $name "(string escape -- $value)
|
|
end
|
|
else
|
|
set --query env[1] && string match --entire --regex -- "^alias" $line || echo "echo \"$line\""
|
|
end
|
|
end | string replace --all -- \$ \\\$
|
|
for name in (set --export --names)
|
|
contains -- $name $env || echo "set --erase $name"
|
|
end
|
|
) | source
|
|
end
|
|
end
|