rootiest
859f14a6e9
Audits every function's interaction with the C1-shadowed commands (uses-shadow/bypasses-shadow) and general hazards (destructive, network, blocking-prompt) per the CLASSIFICATION schema. Delegated the initial mechanical sweep to agy, then reviewed every file by hand: fixed a systemic double-blank-comment-line formatting bug from the delegate pass, and corrected several judgment errors found on review -- three false blocking-prompt tags where a fish 'read' was consuming piped input rather than waiting on a terminal (open-url.fish, sbver.fish, play-media.fish, now untagged entirely), a blocking-prompt tag on mkrep.fish despite its documented --yes escape hatch, an untagged read in jobrunner.fish's own baseless blocking-prompt claim (removed, along with a destructive tag on cleanup of its own mktemp output -- the schema explicitly excludes that), the same own-output-cleanup false positive on _zellij_dump_log.fish's destructive tag, an interactive fzf-gated confirmation on logs.fish and replay.fish's piped read misread the same way as the first three, and a uses-shadow(mkdir) on mkcd.fish that actually belongs to the _fish_mkdir_p helper it delegates to, not to mkcd itself.
37 lines
1.3 KiB
Fish
37 lines
1.3 KiB
Fish
# Copyright (C) 2026 Rootiest
|
|
# SPDX-License-Identifier: AGPL-3.0-or-later
|
|
|
|
# CLASSIFICATION
|
|
# uses-shadow(mkdir)
|
|
#
|
|
# SYNOPSIS
|
|
# _tmux_pipe_log
|
|
#
|
|
# DESCRIPTION
|
|
# Starts tmux pipe-pane capture for the current pane, streaming its output
|
|
# to a timestamped log in SCROLLBACK_HISTORY_DIR (default ~/.terminal_history).
|
|
# Old tmux_*.log files are pruned via _prune_terminal_logs to stay within
|
|
# SCROLLBACK_HISTORY_MAX_FILES. No-op when not inside a tmux session ($TMUX
|
|
# unset) or tmux is missing. Shared by conf.d/tmux-logging.fish (shell
|
|
# startup) and __fish_config_sync_logging (C5 re-enable) so both stay in sync.
|
|
#
|
|
# EXIT STATUS
|
|
# 0 Always
|
|
#
|
|
# EXAMPLE
|
|
# _tmux_pipe_log
|
|
function _tmux_pipe_log --description 'Start tmux pipe-pane capture for the current pane, with pruning'
|
|
set -q TMUX; or return 0
|
|
type -q tmux; or return 0
|
|
|
|
set -l log_dir (set -q SCROLLBACK_HISTORY_DIR; and echo $SCROLLBACK_HISTORY_DIR; or echo "$HOME/.terminal_history")
|
|
set -l pane_id (tmux display-message -p '#{session_name}-w#{window_index}-p#{pane_index}' 2>/dev/null)
|
|
set -l timestamp (date "+%Y-%m-%d_%H-%M-%S")
|
|
set -l log_file "$log_dir/tmux_"$pane_id"_"$timestamp".log"
|
|
|
|
mkdir -p $log_dir
|
|
_prune_terminal_logs tmux
|
|
|
|
tmux pipe-pane "cat >> $log_file" 2>/dev/null
|
|
end
|