rootiest
4c1e7a7eb9
- Core config layered on CachyOS base with Catppuccin Mocha theming - Fisher plugins: fzf.fish, catppuccin, autopair, replay, puffer-fish, magic-enter, spark - Smart CLI wrappers with fallbacks (bat, lsd, btop, dust, prettyping) - Custom functions: git, docker, network, kitty, AI session management - Extensive abbreviation system for keyboard-driven workflows - Secrets/local sourcing pattern for private and machine-specific config - README with full documentation and personalization guide - AGPLv3+ license with copyright headers on all source files
33 lines
1.7 KiB
Fish
33 lines
1.7 KiB
Fish
function _fzf_search_processes --description "Search all running processes. Replace the current token with the pid of the selected process."
|
|
# Directly use ps command because it is often aliased to a different command entirely
|
|
# or with options that dirty the search results and preview output
|
|
set -f ps_cmd (command -v ps || echo "ps")
|
|
# use all caps to be consistent with ps default format
|
|
# snake_case because ps doesn't seem to allow spaces in the field names
|
|
set -f ps_preview_fmt (string join ',' 'pid' 'ppid=PARENT' 'user' '%cpu' 'rss=RSS_IN_KB' 'start=START_TIME' 'command')
|
|
set -f processes_selected (
|
|
$ps_cmd -A -opid,command | \
|
|
_fzf_wrapper --multi \
|
|
--prompt="Processes> " \
|
|
--query (commandline --current-token) \
|
|
--ansi \
|
|
# first line outputted by ps is a header, so we need to mark it as so
|
|
--header-lines=1 \
|
|
# ps uses exit code 1 if the process was not found, in which case show an message explaining so
|
|
--preview="$ps_cmd -o '$ps_preview_fmt' -p {1} || echo 'Cannot preview {1} because it exited.'" \
|
|
--preview-window="bottom:4:wrap" \
|
|
$fzf_processes_opts
|
|
)
|
|
|
|
if test $status -eq 0
|
|
for process in $processes_selected
|
|
set -f --append pids_selected (string split --no-empty --field=1 -- " " $process)
|
|
end
|
|
|
|
# string join to replace the newlines outputted by string split with spaces
|
|
commandline --current-token --replace -- (string join ' ' $pids_selected)
|
|
end
|
|
|
|
commandline --function repaint
|
|
end
|