rootiest
4c1e7a7eb9
- Core config layered on CachyOS base with Catppuccin Mocha theming - Fisher plugins: fzf.fish, catppuccin, autopair, replay, puffer-fish, magic-enter, spark - Smart CLI wrappers with fallbacks (bat, lsd, btop, dust, prettyping) - Custom functions: git, docker, network, kitty, AI session management - Extensive abbreviation system for keyboard-driven workflows - Secrets/local sourcing pattern for private and machine-specific config - README with full documentation and personalization guide - AGPLv3+ license with copyright headers on all source files
22 lines
1.3 KiB
Fish
22 lines
1.3 KiB
Fish
function _fzf_wrapper --description "Prepares some environment variables before executing fzf."
|
|
# Make sure fzf uses fish to execute preview commands, some of which
|
|
# are autoloaded fish functions so don't exist in other shells.
|
|
# Use --function so that it doesn't clobber SHELL outside this function.
|
|
set -f --export SHELL (command --search fish)
|
|
|
|
# If neither FZF_DEFAULT_OPTS nor FZF_DEFAULT_OPTS_FILE are set, then set some sane defaults.
|
|
# See https://github.com/junegunn/fzf#environment-variables
|
|
set --query FZF_DEFAULT_OPTS FZF_DEFAULT_OPTS_FILE
|
|
if test $status -eq 2
|
|
# cycle allows jumping between the first and last results, making scrolling faster
|
|
# layout=reverse lists results top to bottom, mimicking the familiar layouts of git log, history, and env
|
|
# border shows where the fzf window begins and ends
|
|
# height=90% leaves space to see the current command and some scrollback, maintaining context of work
|
|
# preview-window=wrap wraps long lines in the preview window, making reading easier
|
|
# marker=* makes the multi-select marker more distinguishable from the pointer (since both default to >)
|
|
set --export FZF_DEFAULT_OPTS '--cycle --layout=reverse --border --height=90% --preview-window=wrap --marker="*"'
|
|
end
|
|
|
|
fzf $argv
|
|
end
|